akkoma/lib/pleroma/search/database_search.ex

# Pleroma: A lightweight social networking server
# Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
# SPDX-License-Identifier: AGPL-3.0-only

defmodule Pleroma.Search.DatabaseSearch do
  alias Pleroma.Activity
  alias Pleroma.Object.Fetcher
  alias Pleroma.Pagination
  alias Pleroma.User
  alias Pleroma.Web.ActivityPub.Visibility

  require Pleroma.Constants

  import Ecto.Query

  @behaviour Pleroma.Search.SearchBackend

  def search(user, search_query, options \\ []) do
    index_type =
      cond do
        Pleroma.Config.get([:database, :rum_enabled]) -> :rum
        Pleroma.Config.get([:database, :pgroonga_enabled]) -> :pgroonga
        true -> :gin
      end

    can_search_following =
      Pleroma.Config.get([Pleroma.Search, :extensions, :search_option_following], true)

    limit = Enum.min([Keyword.get(options, :limit), 40])
    offset = Keyword.get(options, :offset, 0)
    author = Keyword.get(options, :author)
    following = can_search_following && Keyword.get(options, :following, false)
    only_media = Keyword.get(options, :only_media, false)
    only_local = Keyword.get(options, :local, false)

    try do
      Activity
      |> Activity.with_preloaded_object()
      |> Activity.restrict_deactivated_users()
      |> restrict_public()
      |> query_with(index_type, search_query)
      |> maybe_restrict_local(user, only_local)
      |> maybe_restrict_author(author)
      |> maybe_restrict_blocked(user)
      |> maybe_restrict_following(user, following)
      |> maybe_restrict_media(only_media)
      |> Pagination.fetch_paginated(
        %{"offset" => offset, "limit" => limit, "skip_order" => index_type == :rum},
        :offset
      )
      |> maybe_fetch(user, search_query)
    rescue
      _ -> maybe_fetch([], user, search_query)
    end
  end

  @impl true
  def add_to_index(_activity), do: nil

  @impl true
  def remove_from_index(_object), do: nil

  def maybe_restrict_author(query, %User{} = author) do
    Activity.Queries.by_author(query, author)
  end

  def maybe_restrict_author(query, _), do: query

  def maybe_restrict_following(query, %User{} = user, true) do
    Activity.Queries.by_authors(query, User.following_ap_ids(user))
  end

  def maybe_restrict_following(query, _, _), do: query

  def maybe_restrict_blocked(query, %User{} = user) do
    Activity.Queries.exclude_authors(query, User.blocked_users_ap_ids(user))
  end

  def maybe_restrict_blocked(query, _), do: query

  def restrict_public(q) do
    from([a, o] in q,
      where: fragment("?->>'type' = 'Create'", a.data),
      where: ^Pleroma.Constants.as_public() in a.recipients
    )
  end

  def query_with(q, :gin, search_query) do
    %{rows: [[tsc]]} =
      Ecto.Adapters.SQL.query!(
        Pleroma.Repo,
        "select current_setting('default_text_search_config')::regconfig::oid;"
      )

    from([a, o] in q,
      where:
        fragment(
          "to_tsvector(?::oid::regconfig, ?->>'content') @@ websearch_to_tsquery(?)",
          ^tsc,
          o.data,
          ^search_query
        )
    )
  end

  def query_with(q, :rum, search_query) do
    from([a, o] in q,
      where:
        fragment(
          "? @@ websearch_to_tsquery(?)",
          o.fts_content,
          ^search_query
        ),
      order_by: [fragment("? <=> now()::date", o.inserted_at)]
    )
  end

  def query_with(q, :pgroonga, search_query) do
    from([a, o] in q,
      where:
        fragment(
          "?->'content' &@~ ?",
          o.data,
          ^search_query
        )
    )
  end

  def maybe_restrict_local(q, user, only_local) do
    limit = Pleroma.Config.get([:instance, :limit_to_local_content], :unauthenticated)

    case {only_local, limit, user} do
      {true, _, _} -> restrict_local(q)
      {_, :all, _} -> restrict_local(q)
      {_, :unauthenticated, %User{}} -> q
      {_, :unauthenticated, _} -> restrict_local(q)
      {_, false, _} -> q
    end
  end

  defp restrict_local(q), do: where(q, local: true)

  def maybe_fetch(activities, user, search_query) do
    with true <- Regex.match?(~r/https?:/, search_query),
         {:ok, object} <- Fetcher.fetch_object_from_id(search_query),
         %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
         true <- Visibility.visible_for_user?(activity, user) do
      [activity | activities]
    else
      _ -> activities
    end
  end

  def maybe_restrict_media(q, true) do
    from([a, o] in q,
      where: fragment("not (?)->'attachment' = (?)", o.data, ^[])
    )
  end

  def maybe_restrict_media(q, _), do: q
end